;-----------------------------
; clkm.spi
; PURPOSE: Tuns the 'CL KM' operation
; ASSUMES: Equal weight to all factors, using continuous factors,
; ----------------------------

[f1]   = 1       ; Beginning factor
[f2]   = 3       ; Ending factor
[nc]   = 8       ; Number of classes REQUIRED
[seed] = 453     ; Random number seed

; ---------- INPUT files --------

FR G
[infile]data/control_IMC   ; Data, either SEQ, IMC, or PIX

FR G
[image_template]data/sma***         ; Template for images to be averaged 

; ----------- OUTPUT files ------

FR G
[template]data/clkm_imc_class_{***[seed]}_   ; Cluster assignment doc file prefix

FR G
[doc]data/clkm_imc_class_{***[seed]}        ; Name of cluster membership doc file

FR G
[avg]data/clkm_avg_                ; Class average files      
FR G
[var]data/clkm_var_                ; Class variance files   
FR G
[montage]data/clkm_class_montage   ; Class average montage file    

; ----------- END BATCH HEADER -----

VM
\rm -f [template]* [doc]*

VM
echo " Running 'CL KM' xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx"

CL KM [B],[W],[C],[H],[DB]
[infile]        ; CA/PCA file                  (input)
[nc]            ; Number of classes
[f1]-[f2]       ; Which factors
0               ; Equal weight with factors
[seed]          ; Random starting #
[template]***   ; Template for doc series (output)
[doc]           ; Cluster membership coc file  (outpu)

; Echo operation return values to results file
[B]     ; Tr(B), trace of between-groups sum of squares matrix, 
[W]     ; Tr(W), trace of within-groups sum of squares matrix, 
[C]     ; C = Tr(B)*Tr(W), Coleman criterion, 
[H]     ; H = (Tr(B)/(k-1))/(Tr(W)/(nobj-k)), Harabasz criterion
[DB]    ; DB, Davies-Bouldin criterion. 

VM
echo " Displaying class doc files xxxxxxxxxxxxxxxxxxxxxxxxxxxxx"
VM
gedit [template]*.$DATEXT &
VM
gedit [doc].$DATEXT &


VM
echo " Creating class average files  xxxxxxxxxxxxxxxxxxxxxxxxxx"

[nclass]=8
DO [i]=1,[nclass]
   AS R
   [image_template]    ; Image file template          (input)
   [template]{***[i]}  ; Image selection file
   All                 ; All images
   [avg]{***[i]}       ; Average files               (output)
   [var]{***[i]}       ; Variance files              (output)
ENDDO
 
VM
echo " Creating montage of class averages  xxxxxxxxxxxxxxxxxxxx"

MN                     ; Montage the averages
[avg]***               ; Average files               (input)
1-[nclass]             ; File numbers
[nclass],4             ; Images / row, margin
0                      ; Margin value
[montage]              ; Montage file                (output)


VM
echo " "
EN