; SOURCE: avgfiles.spi 
; PURPOSE: Find average & variance of a series of successive files  (INDEXED)

FR
?ENTER TEMPLATE FOR IMAGE SERIES (E.G. JNK***)?[file]

RR [ngo]
?NUMBER OF FIRST IMAGE?

RR [nend]
?NUMBER OF LAST IMAGE?

FR
?AVERAGE IMAGE (OUTPUT)?[avgimg]
FR
?VARIANCE IMAGE (OUTPUT)?[varimg]

[part] = [nend] - [ngo] + 1  ; Find number of particles

IF ([part] .EQ. 1) THEN      ; Only a file
   CP                        ; Copy image to average
   [file][ngo]               ; Image file                    (input)
   [avgimg]                  ; Average file                  (output)

ELSE

   AS R                      ; Add to average/variance
   [file]                    ; File template       (input)
   [ngo]-[nend]              ; File numbers
   A                         ; Add all images
   [avgimg]                  ; Average file        (output)
   [varimg]                  ; Variance file       (output)
  
ENDIF

FS [max],[min]               ; Get  statistics
[avgimg]                     ; File                     (input)

VM
echo ' Range:     ({%f8.2%[min]} ... {%f8.2%[max]})'

EN