C++*********************************************************************
C
C  CCRS_2.F                      
C      PGI BUG ON: O(I,J) = CTEMP*CONJG(Y(I,J))*CMPLX(COS(ARG),SIN(ARG))
C      PGI BUG                                  FEB 10 2006 ArDean Leith
C      PGI BUG                                  FEB 10 2006 ArDean Leith
C      MOD PGI COMPILER BUG                     FEB 19 2008 ArDean Leith
C      CCRS_2I                                  APR 27 2009 ArDean Leith
C **********************************************************************
C=* FROM: SPIDER - MODULAR IMAGE PROCESSING SYSTEM.   AUTHOR: J.FRANK  *
C=* Copyright (C) 1985-2009  Health Research Inc.                      *
C=*                                                                    *
C=* HEALTH RESEARCH INCORPORATED (HRI),                                *   
C=* ONE UNIVERSITY PLACE, RENSSELAER, NY 12144-3455.                   *
C=*                                                                    *
C=* Email:  spider@wadsworth.org                                       *
C=*                                                                    *
C=* This program is free software; you can redistribute it and/or      *
C=* modify it under the terms of the GNU General Public License as     *
C=* published by the Free Software Foundation; either version 2 of the *
C=* License, or (at your option) any later version.                    *
C=*                                                                    *
C=* This program is distributed in the hope that it will be useful,    *
C=* but WITHOUT ANY WARRANTY; without even the implied warranty of     *
C=* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU  *
C=* General Public License for more details.                           *
C=*                                                                    *
C=* You should have received a copy of the GNU General Public License  *
C=* along with this program; if not, write to the                      *
C=* Free Software Foundation, Inc.,                                    *
C=* 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.      *
C=*                                                                    *
C **********************************************************************
C
C  CCRS_2(X,Y,O,LS,NSAM,NROW)
C
C  PURPOSE: CALCULATES CIRCULAR CROSCORRELATION, NON-POWER-OF-TWO 
C           DIMENSIONS
C
C  PARAMETERS:  X,Y  FOURIER TRANSFORMS                    (SENT)
C               O    F(X*CONJG(Y))                         (RET.)
C               LS   NSAM+2-MOD(NSAM,2)                    (SENT)
C
C NOTE:  USE CCRS_2I WHEN: O IS SAME ADDRESS AS X!!!!!
C
C23456789012345678901234567890123456789012345678901234567890123456789012
C--*********************************************************************
 
        SUBROUTINE CCRS_2(X,Y,O, LS,NSAM,NROW)

C       REAL   X((NSAM+2-MOD(NSAM,2)),NROW,NSLICE)
C       ABOVE ON PGI COMPILER 7.1 FAILS TO COMPILE PROPERLY SOMETIMES

        REAL  :: X(LS,NROW)
        REAL  :: Y(LS,NROW)
        REAL  :: O(LS,NROW)
 
	PARAMETER (QUADPI = 3.1415926535897932384)
	PARAMETER (PI2=2*QUADPI)

        ITMP = NSAM / 2
        SX   = PI2 * FLOAT(ITMP)/FLOAT(NSAM)
        ITMP = NROW / 2
        SY   = PI2 * FLOAT(ITMP )/ FLOAT(NROW)

C$omp   parallel do private(i,j,iy,argy,arg,tmpr,tmpi)
        DO J=1,NROW
           IY = J - 1
           IF (IY .GT. (NROW/2)) IY = IY - NROW
           ARGY = SY * IY

           DO I=1,LS,2
              ARG      = SX * (I-1)/2 + ARGY
    	      TMPR     = X(I,J)   * Y(I,J)  + X(I+1,J) * Y(I+1,J)
	      TMPI     = X(I+1,J) * Y(I,J)  - X(I,J)   * Y(I+1,J)
	      O(I,J)   = TMPR * COS(ARG) - TMPI * SIN(ARG)
	      O(I+1,J) = TMPI * COS(ARG) + TMPR * SIN(ARG)
           ENDDO
        ENDDO

        INS = -1
        CALL FMRS_2(O,NSAM,NROW,INS)

        END


C      --------------- CCRS_2I -------------------------------------

       SUBROUTINE CCRS_2I(X,Y, LS,NSAM,NROW)

C       REAL   X((NSAM+2-MOD(NSAM,2)),NROW,NSLICE)

        REAL  :: X(LS,NROW)
        REAL  :: Y(LS,NROW)
 
	PARAMETER (QUADPI = 3.1415926535897932384)
	PARAMETER (PI2=2*QUADPI)

        ITMP = NSAM / 2
        SX   = PI2 * FLOAT(ITMP) / FLOAT(NSAM)
        ITMP = NROW / 2
        SY   = PI2 * FLOAT(ITMP ) / FLOAT(NROW)

C$omp   parallel do private(i,j,iy,argy,arg,tmpr,tmpi)
        DO J=1,NROW
           IY = J - 1
           IF (IY .GT. (NROW/2)) IY = IY - NROW
           ARGY = SY * IY

           DO I=1,LS,2
              ARG      = SX * (I-1)/2 + ARGY
    	      TMPR     = X(I,J)   * Y(I,J)  + X(I+1,J) * Y(I+1,J)
	      TMPI     = X(I+1,J) * Y(I,J)  - X(I,J)   * Y(I+1,J)
	      X(I,J)   = TMPR * COS(ARG) - TMPI * SIN(ARG)
	      X(I+1,J) = TMPI * COS(ARG) + TMPR * SIN(ARG)
           ENDDO
        ENDDO

        INS = -1
        CALL FMRS_2(X,NSAM,NROW,INS)

        END




#ifdef NEVER
	      OREAL = TMPR * COS(ARG) - TMPI * SIN(ARG)
	      OIMG  = TMPI * COS(ARG) + TMPR * SIN(ARG)
		 
	      O(I,J)   = OREAL
              O(I+1,J) = OIMG		 
#endif