C++*********************************************************************
C
C OPENCHK.F -- NEW NOVEMBER 1996  AUTHOR: ARDEAN LEITH
C              NSAM, NROW, NSLICE ALL ON ONE LINE AUG 2002 ARDEAN LEITH
C              'MS' MODIFICATIONS                 AUG 2002 ARDEAN LEITH
C           
C **********************************************************************
C=* FROM: SPIDER - MODULAR IMAGE PROCESSING SYSTEM.   AUTHOR: J.FRANK  *
C=* Copyright (C) 1985-2005  Health Research Inc.                      *
C=*                                                                    *
C=* HEALTH RESEARCH INCORPORATED (HRI),                                *   
C=* ONE UNIVERSITY PLACE, RENSSELAER, NY 12144-3455.                   *
C=*                                                                    *
C=* Email:  spider@wadsworth.org                                       *
C=*                                                                    *
C=* This program is free software; you can redistribute it and/or      *
C=* modify it under the terms of the GNU General Public License as     *
C=* published by the Free Software Foundation; either version 2 of the *
C=* License, or (at your option) any later version.                    *
C=*                                                                    *
C=* This program is distributed in the hope that it will be useful,    *
C=* but WITHOUT ANY WARRANTY; without even the implied warranty of     *
C=* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU  *
C=* General Public License for more details.                           *
C=*                                                                    *
C=* You should have received a copy of the GNU General Public License  *
C=* along with this program; if not, write to the                      *
C=* Free Software Foundation, Inc.,                                    *
C=* 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.      *
C=*                                                                    *
C **********************************************************************
C
C   OPENCHK(NSAM,NROW,NSLICE,ITYPE,NSAMAX,IRTFLG)
C
C    PURPOSE:       CHECK ON INFO TO OPEN A NEW SPIDER IMAGE.
C
C    PARAMETERS:
C        NSAM,NROW  DIMENSIONS OF FILE                     (SENT)
C        NSLICE     NUMBER OF PLANES                       (SENT)
C        ITYPE      IFORM                                  (SENT/RET.)                    
C        NSAMAX     MAX. RECORD SIZE                       (SENT)                    
C        IRTFLG     ERROR RETURN FLAG.                     (RET.)
C                   IRTFLG = 0    NORMAL RETURN
C                   IRTFLG = 1    ERROR RETURN
C
C23456789 123456789 123456789 123456789 123456789 123456789 123456789 12
C--*********************************************************************

      SUBROUTINE OPENCHK(NSAM,NROW,NSLICE,ITYPE,NSAMAX,IRTFLG)

      INCLUDE 'CMBLOCK.INC'
	
C     CHECK THAT INPUT PARAMETERS ARE OK
C     IF NSAM OR NROW IS NOT LOGICAL ASK FOR THEM

      IF ((ITYPE .EQ. 0  .OR. ITYPE .EQ. -1 ) .AND.  NSLICE .LE. 0) THEN
C        NEED TO INQUIRE DIMENSIONS (FROM 'MS')
         CALL RDPRI3S(NSAM,NROW,NSLICE,NOT_USED,
     &              'ENTER DIMENSIONS (NSAM,NROW,NSLICE)',IRTFLG)
         IF (IRTFLG .NE. 0) RETURN

         IF (ITYPE .EQ. -1 .AND. NSLICE .LE. 1)  THEN
C          FOURIER IMAGE STACK
           ITYPE  = -12 + MOD(NSAM,2)
           NSLICE = 1
           
         ELSEIF (ITYPE .EQ. -1)  THEN
C          FOURIER VOLUME STACK
           ITYPE = -22 + MOD(NSAM,2)

         ELSEIF (NSLICE .LE. 1) THEN
C           IMAGE STACK
            NSLICE = 1
            ITYPE  = 1
         ELSE
C           VOLUME STACK
            ITYPE  = 3
         ENDIF

      ELSEIF (ITYPE .EQ. 3 .AND. NSLICE .LE. 0) THEN
C        NEED TO INQUIRE DIMENSIONS FROM OTHER OPS THAN 'MS'
         CALL RDPRI3S(NSAM,NROW,NSLICE,NOT_USED,
     &              'ENTER DIMENSIONS (NSAM,NROW,NSLICE)',IRTFLG)
         IF (IRTFLG .NE. 0) RETURN

         IF (NSLICE .EQ. -9999) THEN
C           SET NSLICE TO 1
            NSLICE = 1

         ELSEIF (NSLICE .LE. 0) THEN
C           STILL NEED TO INQUIRE AS TO NSLICE
            CALL RDPRI1S(NSLICE,NOT_USED,
     &                 'ENTER Z DIMENSION (NSLICE)',IRTFLG)
         ENDIF
         IF (IRTFLG .NE. 0) RETURN

         IF (NSLICE .LE. 1) ITYPE = 1

      ELSEIF (NSAM .LE. 0 .OR. NROW .LE. 0) THEN
C        NEED TO FIND NSAM & NROW FOR NEW FILE
         NROW = 0
         CALL RDPRIS(NSAM,NROW,NOT_USED,
     &               'ENTER X & Y DIMENSIONS (NSAM,NROW)',IRTFLG)
         IF (IRTFLG .NE. 0) RETURN
         IF (ITYPE .EQ. 0) ITYPE = 1
      ENDIF
      IRTFLG = 1
      IF (NROW .LE. 0) NROW = NSAM

      IF (NSAM .LE. 0 .OR. NROW .LE. 0) THEN
C        FOR NEW FILES, NON-ZERO NSAM, NROW NEED TO BE SUPPLIED
         CALL ERRT(101,'NSAM OR NROW NOT GIVEN',NE)
         RETURN

      ELSEIF (NSAM .GT. NSAMAX) THEN
C        EXCESSIVE ROW LENGTH 
         WRITE(NOUT,*) '*** ROWLENGTH MUST BE <=:',NSAMAX
         CALL ERRT(100,'OPENCHK',NE)
         RETURN

      ELSEIF (NSLICE .EQ. 0) THEN
C        NEW FILES NEED A NON ZERO SLICE NUMBER
         NSLICE = 1

      ELSEIF (NSLICE .LT. 0) THEN
C        WANT TO CREATE OBSOLETE SHORT HEADER FILE
         WRITE(NOUT,*) 
     &            'WARNING:  SHORT HEADER FILES NO LONGER SUPPORTED.'
         NSLICE = -NSLICE
      ENDIF

      IF (ITYPE .EQ. -1 .OR. ITYPE .EQ. -3 .OR. ITYPE .EQ. -7) THEN
C        WANT TO CREATE OBSOLETE FOURIER FILE
         CALL ERRT(101,
     &         'CAN NOT CREATE OBSOLETE FOURIER FORMAT FILE',NE)
         RETURN

      ELSEIF (ITYPE .EQ. 0) THEN
C        WANT TO CREATE ???? TYPE
         CALL ERRT(101, 'PGM. ERROR, UNKNOWN FILE FORMAT',NE)
         RETURN

      ENDIF

      IRTFLG = 0
      RETURN

      END