C ++********************************************************************
C                                                                      *
C  PREPCUB_Q                          SPEEDED UP FEB 2000 ARDEAN LEITH
C                                                                      *
C **********************************************************************
C=* FROM: SPIDER - MODULAR IMAGE PROCESSING SYSTEM.   AUTHOR: J.FRANK  *
C=* Copyright (C) 1985-2005  Health Research Inc.                      *
C=*                                                                    *
C=* HEALTH RESEARCH INCORPORATED (HRI),                                *   
C=* ONE UNIVERSITY PLACE, RENSSELAER, NY 12144-3455.                   *
C=*                                                                    *
C=* Email:  spider@wadsworth.org                                       *
C=*                                                                    *
C=* This program is free software; you can redistribute it and/or      *
C=* modify it under the terms of the GNU General Public License as     *
C=* published by the Free Software Foundation; either version 2 of the *
C=* License, or (at your option) any later version.                    *
C=*                                                                    *
C=* This program is distributed in the hope that it will be useful,    *
C=* but WITHOUT ANY WARRANTY; without even the implied warranty of     *
C=* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU  *
C=* General Public License for more details.                           *
C=*                                                                    *
C=* You should have received a copy of the GNU General Public License  *
C=* along with this program; if not, write to the                      *
C=* Free Software Foundation, Inc.,                                    *
C=* 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.      *
C=*                                                                    *
C **********************************************************************
C                                                                      *
C  PREPCUB_Q(BCKE,NSAM,NROW,NSLICE,BUF,NN,NMAT,IPCUBE,RI,INPIC,MD)                                                                   *
C                                                                      *
C  PURPOSE:  CREATES IPCUBE & BCKE                                                          *
C                                                                      *
C  PARAMETERS:   BCKE          VOLUME                             RET.
C                BUF           IO BUFFER                          SENT
C                NN            NO. OF ROWS                        RET.
C                IPCUBE                                           RET.
C                NMAT                                             RET.
C                RI            RADIUS                             SENT
C                INPIC         INPUT UNIT                         SENT
C 
C
C  NOTES:                                                              *
C           
C     IPCUBE:    1 - BEGINNING
C                2 - LENGTH
C                3 - IX
C                4 - IY
C                5 - IZ
C
C IMAGE_PROCESSING_ROUTINE
C                                                                      *
C        0         2         3         4         5         6         7 *
C23456789012345678901234567890123456789012345678901234567890123456789012
C***********************************************************************

        SUBROUTINE PREPCUB_Q
     &      (BCKE,NSAM,NROW,NSLICE,BUF,NN,NMAT,IPCUBE,RI,INPIC,MD)

        INTEGER       IPCUBE(5,NN)
        DIMENSION     BCKE(NMAT),BUF(NSAM)
        LOGICAL       FIRST,MD
        COMMON /PAR/  LDPX,LDPY,LDPZ

        R    = RI * RI
        NMAT = 0
        NN   = 0

        DO I1=1,NSLICE
           T  = I1 - LDPZ
           XX = T * T

           DO I2=1,NROW
              T     = I2 - LDPY
              YY    = T * T+XX
              FIRST = .TRUE.

              DO I3=1,NSAM
                 T  = I3 - LDPX
                 RC = T * T + YY

                 IF (FIRST) THEN
C                   FIRST PIXEL ON THIS LINE,
                    IF (RC .GT. R)  CYCLE
                    FIRST = .FALSE.

                    NMAT         = NMAT + 1
                    IF (MD) THEN
C                     READ INPUT LINE
                       CALL REDLIN(INPIC,BUF,NSAM,I2+(I1-1)*NROW)
                       BCKE(NMAT)   = BUF(I3)
                    ENDIF
                    NN           = NN + 1
                    IF (MD) THEN
                       IPCUBE(1,NN) = NMAT
                       IPCUBE(2,NN) = NMAT
                       IPCUBE(3,NN) = I3
                       IPCUBE(4,NN) = I2
                       IPCUBE(5,NN) = I1
                    ENDIF
                 ELSE
C                   SECOND OR LATER PIXEL ON THIS LINE,
                    IF (RC .GT. R) EXIT
                    NMAT         = NMAT + 1
                    IF (MD) THEN
                       BCKE(NMAT)   = BUF(I3)
                       IPCUBE(2,NN) = NMAT
                    ENDIF
                 ENDIF
              ENDDO
           ENDDO        
        ENDDO

C        CLOSE(INPIC)
        END